Shader入门精要-标准光照模型

基础概念

光源

在实时渲染中我们通常把光源当做一个没有体积的点，用 l 来表示它的方向

辐照度

在光学里，使用**辐照度（irradiance）**来量化光。对于平行光来说，它的辐照度可以通过计算在垂直于光的方向的单位面积上单位时间内穿过的能量来得到。

对于平行光来说，它的辐照度可以通过计算垂直于 l 的单位面积上单位时间内穿过的能量来量化光

对于非平行光，使用光源方向 l 和表面法线 n 之间的夹角的余弦值来得到。需要注意的是默认方向矢量的模都是1。

使用点积来计算辐照度的由来

由上图可以看出，因为辐照度是和照射到的物体表面时光线之间的距离 d/cosθ 成反比，因此辐照度和 cosθ 成正比。cosθ 可以使用光源 l 和表面法线 n 的点积来得到。

吸收和散射

光线由光源发射出来后，就会与一些物体交互。通常相交的结果只有两个：散射（scattering）和吸收（absorption）

散射

散射只改变光线的方向，但不改变光线的密度和颜色

光线在物体表面经过散射后，会产生两种方向：

折射或透射

这种方式会将光线散射到物体内部
反射

这种方式会将光线散射到物体外部

为了区分这两种不同的散射方向，我们在光照模型中使用了不同的部分来计算他们：

高光反射

表示物体表面是如何反射光线的
漫反射

表示物体有多少光线会被折射吸收和散射出表面。

吸收

吸收只改变光线的密度和颜色，但不改变光线的方向

出射度

根据入射光线的数量和方向，我们可以计算出射光线的数量和方向，我们通常用出射度来描述它。

辐照度和出射度之间是满足线性关系的，而他们之间的比值就是材质的漫反射和高光反射属性。

标准光照模型

标准光照模型只关心直接光照，也就是那些直接从光源发射出来照射到物体表面后，经过物体表面的一次反射直接进入摄像机的光线。

它的基本方法是，把进入摄像机内的光线分为4个部分，每个部分使用一种方法计算它的贡献度：

自发光（emissive）部分

部分用来描述当给定一个方向时，一个表面本身会向该方向发射多少辐射量。需要注意的是，如果没有使用全局光照（global illumination）技术，这些自发光的表面并不会真的照亮周围的物体，而是它本身看着更亮了。
反射（specular）部分

来描述当光线照到模型表面时，该表面会在完全镜面反射方向散射多少辐射量。
反射（diffuse）部分

照到模型表面时，表面会向每个方向散射多少辐射量。
光（ambient）部分

其他所有的间接光照。

环境光

间接光照：光线通常会在多个物体之间反射，最后进入摄像机，也就是说，在光线进入摄像机之前，经过了不止一次的物体反射。

标准光照模型中，使用一种被称为环境光的部分来近似模拟间接光照。环境光的通常是一个全局变量，既场景中所有物体都使用这个环境光。在Shader中，该内置变量为UNITY_LIGHTMODEL_AMBIENT，在Unity中可以在Windwos->Rendering->LightingSettings->EnvironmetLighting中设置该参数。

自发光

光照可以直接由光源发射进入摄像机，而不需要经过任何物体的反射。在标准光照模型中，直接使用该材质的自发光颜色。

漫反射

用于对那些被物体表面随机散射到各个方向的辐射度进行建模。

兰伯特光照模型

漫反射光照符合兰伯特定律（Lambert‘s law）：反射光线的强度与表面法线和光源方向之间夹角的余弦值成正比。

C = (c * m) * max( 0 , n * l )

n是表面法线，I是指向光源的单位矢量，m是材质的漫反射颜色，c是光源颜色。需要注意应该防止法线和光源点乘的结果为负值（避免物体被从后面来的光源照亮），所以用max函数限制其为正数。

半兰伯特光照模型

在光照无法达到的区域，模型的外观通常是全黑的，没有仍和明暗变化，这会使模型的背光去看起来像一个平面，失去了模型的细节。

为解决这一问题，Valve公司在开发《半条命》时提出了一种技术，该技术在兰伯特光照模型的基础上进行了一个简单的修改，因此被称之为半兰伯特光照模型。

C = (c * m) * ( a ( n * l ) + β )

与兰伯特相比，半兰伯特没有使用max操作来防止法线和光源点乘的结果为负值，而是对其结果进行了一个a倍的缩放，再加上一个β大小的偏移。绝大多数情况下，a和β的值都为0.5，即公式为：

C = (c * m) * ( 0.5 ( n * l ) + 0.5 )

需要注意的是，半兰伯特是没有任何物理依据的，它仅仅是一个视觉加强技术。

高光反射

高光反射并不完全符合真实射界中的高光反射现象。

计算高光反射需要知道的信息比较多，如表面法线、视角方向、光源方向、反射方向等。其中反射方向计算公式如下：

r = 2(n * l)n - l

在Cg语法中提供了计算反射方向的函数：reflect(i,n);其中参数i代表入射方向，n代表法线方向。

Phong模型

C = (c * m) * (max(0,v * r)) ^ gloss

n是表面法线，I是指向光源的单位矢量，r为光的反射方向矢量，m为高光反射颜色， v 为视角方向矢量，gloss为材质的光泽度，gloss越大亮点就越小。

同样这里也需要法线和光源点乘的结果为负值

Blinn模型

C = ( c * m) * (max( 0, n * h ))^gloss

与上述Phong模型不同的是，Blinn模型引入了一个新矢量h，通过对 v 和 l的取平均后再归一化得到：

h = ( v + l ) / | v + l |

对比

在硬件实现时，如果摄像机的光源距离模型足够远的话，Blinn模型会快于Phong模型，这是因为可认为法线v和光源方向l都是定值，因此h是一个常量。

当法线和光源方向不是定值时，Phong模型可能反而更快。

需要注意两种模型都是经验模型，一些情况下Blinn模型更加符合实验结果。

内建函数

这里将出示在本文中会用到的Unity内建函数

代码实现

逐顶点漫反射光照

Shader "Unity Shaders Book/Chapter 6/Diffuse Vertex-Level"
{
    Properties
    {
        // 用于控制物体颜色
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
    }
    SubShader
    {
        Pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"
            
            fixed4 _Diffuse;
            
            struct a2v
            {
                float4 vertex: POSITION;
                float3 normal: NORMAL;
            };
            
            struct v2f
            {
                float4 pos: SV_POSITION;
                fixed3 color: COLOR;
            };
            
            v2f vert(a2v v)
            {
                v2f o;
                // 将顶点从对象空间转换到投影空间
                o.pos = UnityObjectToClipPos(v.vertex);
                
                // 获取环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                // 将法线从物体空间转换到世界空间
                //fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
                fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
                // 获得世界空间的光方向
                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
                // 漫反射光=入射光线强度*材质的漫反射系数*取值为正数(表面法线方向 · 光源方向)
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
                
                // 最终结果=环境光+漫反射光
                o.color = ambient + diffuse;
                
                return o;
            }
            
            fixed4 frag(v2f i): SV_Target
            {
                return fixed4(i.color, 1.0);
            }
            
            ENDCG
            
        }
    }
    FallBack "Diffuse"
}

逐像素漫反射光照

			v2f vert(a2v v)
            {
                v2f o;
                // 将顶点从对象空间转换到投影空间
                o.pos = UnityObjectToClipPos(v.vertex);

                // 将法线从物体空间转换到世界空间
                // o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
                o.worldNormal = UnityObjectToWorldDir(v.normal);

                return o;
            }
            
            fixed4 frag(v2f i): SV_Target
            {
                // 获取环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                // 得到世界空间的法线
                fixed3 worldNormal = normalize(i.worldNormal);
                // 获得世界空间的光方向
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                
                // 漫反射光=入射光线强度*材质的漫反射系数*取值为正数(表面法线方向 · 光源方向)
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
                
			   // 最终结果=环境光+漫反射光
                fixed3 color = ambient + diffuse;
                
                return fixed4(color, 1.0);
            }

半罗伯特光照

 			fixed4 frag(v2f i): SV_Target
            {
                // 获取环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                // 得到世界空间的法线
                fixed3 worldNormal = normalize(i.worldNormal);
                // 获得世界空间的光方向
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                
                // 计算半兰伯特模型
                fixed halfLambert = dot(worldNormal, worldLightDir) * 0.5 + 0.5;
                // 漫反射光=入射光线强度*材质的漫反射系数*半兰伯特模型
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * halfLambert;
                
                // 最终结果=环境光+漫反射光
                fixed3 color = ambient + diffuse;
                
                return fixed4(color, 1.0);
            }

逐顶点高光反射光照

Shader "Unity Shaders Book/Chapter 6/Specular Vertex-Level"
{
    Properties
    {
		// 用于控制物体颜色
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
		// 用于控制高光颜色
        _Specular ("Specular", Color) = (1, 1, 1, 1)
		// 用于控制高光区域大小
        _Gloss ("Gloss", Range(8.0, 256)) = 20
    }
    SubShader
    {
        Pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"
            
            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;
            
            struct a2v
            {
                float4 vertex: POSITION;
                float3 normal: NORMAL;
            };
            
            struct v2f
            {
                float4 pos: SV_POSITION;
                fixed3 color: COLOR;
            };
            
            v2f vert(a2v v)
            {
                v2f o;
                // 将顶点从对象空间转换到投影空间
                o.pos = UnityObjectToClipPos(v.vertex);
                
                // 获取环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                // 将法线从物体空间转换到世界空间
                //fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
                fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);

                // 获得世界空间的光方向
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                
                // 漫反射光=入射光线强度*材质的漫反射系数*取值为正数(表面法线方向 · 光源方向)
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
                
                // 获得世界空间的反射方向=表面法线方向和光源方向   reflect用于计算反射方向（入射方向和法线方向）
                fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));

                // 获得世界空间的视角方向=相机位置-世界模型顶点位置
                //fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);
                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(mul(unity_ObjectToWorld, v.vertex)));

                // 高光反射=入射光线颜色强度*材质的高光反射系数*n次平方(取值为正数(反射方向 · 视角方向));		pow：次平方
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);
                
                // 最终结果=环境光+漫反射+高光反射
                o.color = ambient + diffuse + specular;
                
                return o;
            }
            
            fixed4 frag(v2f i): SV_Target
            {
                return fixed4(i.color, 1.0);
            }
            
            ENDCG
            
        }
    }
    FallBack "Specular"
}

逐像素高光反射光照（Phong光照模型）

            v2f vert(a2v v)
            {
                v2f o;
                // 将顶点从对象空间转换到投影空间
                o.pos = UnityObjectToClipPos(v.vertex);
                
                // 将法线从物体空间转换到世界空间
                // o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
                o.worldNormal = UnityObjectToWorldDir(v.normal);

                // 将顶点从对象空间转换到世界空间
                // o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                o.worldPos = UnityObjectToWorldDir(v.vertex);
                
                return o;
            }
            
            fixed4 frag(v2f i): SV_Target
            {
                // 获取环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                // 得到世界空间的法线
                fixed3 worldNormal = normalize(i.worldNormal);
                // 获得世界空间的光方向
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                
                // 漫反射光=入射光线强度*材质的漫反射系数*取值为正数(表面法线方向 · 光源方向)
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
                
                // 得到世界空间的反射方向  reflect用于计算反射方向（入射方向和法线方向）
                fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
                // 获得世界空间的视角方向
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
                // 高光反射=入射光线颜色强度*材质的高光反射系数*n次平方(取值为正数(反射方向 · 视角方向));	pow：次平方
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);
                
                // 最终结果=环境光+漫反射+高光反射,1.0代表透明度
                return fixed4(ambient + diffuse + specular, 1.0);
            }

逐像素高光反射光照（Blinn-Phong光照模型）

            fixed4 frag(v2f i): SV_Target
            {
                // 获取环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                // 得到世界空间的法线
                fixed3 worldNormal = normalize(i.worldNormal);
                // 利用Unity内置功能计算世界空间的光方向
                // 记住要将结果标准化
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                
                // 漫反射光=入射光线强度*材质的漫反射系数*取值为正数(表面法线方向 · 光源方向)
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));
                
                // 利用内建函数计算世界空间的视角方向
                // 记住要使结果标准化
                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));

                // 半角方向
                fixed3 halfDir = normalize(worldLightDir + viewDir);
                // BlinnPhong高光反射=入射光线颜色强度*材质的高光反射系数*n次平方(取值为正数(法线方向 · 半角方向));		pow：次平方
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
                
                // 最终结果=环境光+漫反射+高光反射,1.0代表透明度
                return fixed4(ambient + diffuse + specular, 1.0);
            }